CSE3101 Fall 2005 Exam #1, open book, open notes.  Name ___________________

For all questions, you may use masm, nasm, or gas.  Assume IA-32 (x86)
architecture with C calling conventions where all registers except
eax, ecx, edx and flags are preserved across function calls.

1. Write a C function f() equivalent to the following (15 pts):

_f:
  mov eax, [esp+4]
  lea eax, [eax+eax*4]
  sal eax, 1
  ret

  // ANSWER.  (lea works like mov with the [] removed, so
  // the above multiplies eax * 5)

  int f(int a) {
    return a*10;  // I will accept equivalent expressions like (a*4+a)<<1
  }


2. Convert the following to assembler (30 pts each).

  // Return sum of a[0]+a[1]+...+a[n-1]
  int addup(unsigned char* a, int n) {  // assume n > 0
    int sum=0, i;
    for (i=0; i<n; ++i)
      sum += a[i];
    return sum;
  }

  ; ANSWER.  The most common error is not converting a[i] (one byte)
  ; before adding to sum (4 bytes).  Since a[i] is unsigned, this
  ; can be done by zero extending.

  _addup:
    mov edx, [esp+4] ; a
    mov ecx, [esp+8] ; n, will count down to 1
    xor eax, eax ; sum = 0
    push ebx     ; we will need 4 registers
    xor ebx, ebx ; the high 24 bits will be used for zero extension
  top:
    mov bl, byte ptr [edx+ecx-1]  ; load a[n-1]...a[0] into low byte of ebx
    add eax, ebx
    dec ecx
    jnz top
    pop ebx
    ret


  // Return maximum of three integers (code not shown).
  int max3(int a, int b, int c);

  ; ANSWER.  The most common error was using unsigned comparison
  ; (ja, jb) rather than signed (jg, jl).  Another problem was
  ; trying to compare two memory locations.  An instruction can
  ; only address one memory location at a time.

  _max3:
    mov eax, [esp+4]  ; a
    cmp eax, [esp+8]  ; b
    jl b_or_c
    cmp eax, [esp+12] ; c
    jl b_or_c
    ret               ; a is largest
  b_or_c:
    mov eax, [esp+8]  ; b
    cmp eax, [esp+12] ; c
    jg b
    mov eax, [esp+12] ; c is largest
  b:
    ret


3.  Suppose a and b are qwords (as in "a dq 0") representing 64-bit unsigned
integers in the usual little-endian format.  Write code to add b to
a (as in a=a+b;) (25 pts).

  ; ANSWER.  Common errors were forgetting that a and b are 2 dwords
  ; each, or not putting the result back in a.  Little-endian means
  ; the low bytes are first.

  mov eax, [b]
  add [a], eax    ; sets carry flag
  mov eax, [b+4]  ; mov preserves flags
  adc [a+4], eax